feat: Moves playbook into resources of cli-client.

Sources/CliClient/Resources/ansible-hpa-playbook/justfile

@@ -0,0 +1,36 @@
+[private]
+default:
+  just --list
+
+# Run the playbook with the passed in arguments.
+[group('plays')]
+run *ARGS:
+  @ansible-playbook ./main.yml \
+    --inventory ./inventory.ini \
+    {{ARGS}}
+
+# Run the repo-template option in the `dir` with the passed in arguements.
+[group('plays')]
+create-repo-template dir *ARGS:
+  @just run \
+    --tags repo-template \
+    --extra-vars output_dir={{dir}} \
+    {{ARGS}}
+
+# Run the build-project option in the `dir` with the passed in arguements.
+[group('plays')]
+build-project dir *ARGS:
+  @just run \
+    --tags build-project \
+    --extra-vars project_dir={{dir}} \
+    {{ARGS}}
+
+# Setup a new consult project from a template repo.
+[group('plays')]
+setup-project repo-url version project-dir *ARGS:
+  @ansible-playbook ./main.yml \
+    --inventory ./inventory.ini \
+    --tags setup-project \
+    --extra-vars "{'template': {'repo': {'url': '{{repo-url}}', 'version': '{{version}}' }}}" \
+    --extra-vars "project_dir={{project-dir}}" \
+    {{ARGS}}