playbook_dir := "${ANSIBLE_LOCAL}/ansible-hpa-playbook"
build_dir_name := ".build"

[private]
default:
  just --list

[private]
run_pandoc dir output_file: build
  @pandoc --pdf-engine=xelatex \
    -H {{build_dir_name}}/"head.tex" \
    -H {{build_dir_name}}/"footer.tex" \
    -o {{dir}}/{{output_file}} \
    {{build_dir_name}}/"Report.md" \
    {{build_dir_name}}/"Definitions.md"

[private]
run-playbook *ARGS:
  @ansible-playbook {{playbook_dir}}/main.yml \
    --inventory {{playbook_dir}}/inventory.ini \
    --extra-vars "output_dir={{justfile_directory()}}" \
    --extra-vars "project_dir={{justfile_directory()}}" \
    {{ARGS}}

# Builds and fills the templates into the .build directory.
[group('build')]
build: (run-playbook "--tags build-project")

# Build & generate an HTML report.
[group("generate")]
html title="Report.html" output_dir=".build": (
  run_pandoc output_dir file_stem(title) + ".html"
)
  open {{output_dir}}/{{ prepend(file_stem(title), ".html") }}

# Build & generate a PDF report.
[group("generate")]
pdf title="Report.pdf" output_dir="${PWD}": (run_pandoc output_dir file_stem(title) + ".pdf")
  open {{output_dir}}/{{ prepend(file_stem(title), ".pdf") }} && \
  @osascript ./scripts/notify.scpt

# Build & generate a Latex file.
[group("generate")]
[group("debug")]
tex title="Report.tex" output_dir=".build": (run_pandoc output_dir file_stem(title) + ".tex")
  @echo "Wrote to: " + {{output_dir}}/{{file_stem(title)}} + ".tex"

[group('utilities')]
edit-vault:
  @ansible-vault edit ./vault.yml

[group('utilities')]
clean:
  @rm -rf {{build_dir_name}}